DD包封装相关-(批处理)一键给官方kvm驱动文件夹,驱动细分类

nat.ee · 发表于 2021-11-2 18:38:00

本帖最后由 nat.ee 于 2021-11-2 19:08 编辑

由于自己随着封装年长，封装了越来越多各种不同版本windows系统。

但是，这个kvm官方驱动文件夹，不方便设计的分类存放，每次我都要手动细分每个系统对应的所有相关驱动，这就造成反复到每个相关驱动文件夹下，一层层打开而复制出来存放到相关文件夹，工作繁琐，一气之下，用批处理想了思路写了出来。

我不建议你们封装添加驱动的时候，直接把这个iso文件夹全部添加进系统，这会导致很多不属于此系统版本的驱动都一并导入了。

所以这就有了这个细分类有必要的操作。

kvm 驱动下载 https://fedorapeople.org/groups/virt/virtio-win/direct-downloads/
下载iso文件，里面全部解压到一个文件夹，没有的，新建一个解压全部到这文件夹。

然后复制此批处理到这个文件夹下，点击执行就行。

会在你的桌面自动新建一个目录，并且将细分类好的各系统(amd64/arm64/x86) 此版本对应所有kvm相关文件夹驱动存放复制到。

@echo OFF
::网址: nat.ee
::QQ群: 6281379
::TG群: https://t.me/nat_ee
::批处理: 荣耀&制作 QQ:1800619
title 一键-virtio-win-driver-驱动分类
color 17
pushd "%~dp0"
SET DirDesktop=%USERPROFILE%\Desktop\virtio-win-driver
IF EXIST "%DirDesktop%" (rmdir /s /q "%DirDesktop%")
for /f %%a in ('dir /a:d /b %~dp0NetKVM') do (call :SystemDir %%a)
ECHO.
title 一键-virtio-win-driver-驱动已分类完成。
color 2F
START "" "%DirDesktop%"
ECHO 按任意键退出.....
PAUSE >NUL
ECHO.
exit
:SystemDir
SET KvmSystem=%~1
for /f %%b in ('dir /a:d /b %~dp0') do (call :DriverDir %%b)
goto:eof
exit
:DriverDir
SET KvmDriver=%~1
SET amd64Dir=%DirDesktop%\%KvmSystem%\amd64\%KvmDriver%
SET arm64Dir=%DirDesktop%\%KvmSystem%\ARM64\%KvmDriver%
SET x86Dir=%DirDesktop%\%KvmSystem%\x86\%KvmDriver%
for /f %%c in ('dir /b /s "%~dp0%KvmDriver%\%KvmSystem%\amd64" 2^>NUL ^| FINDSTR /c:"\.cat" /c:"\.inf" /c:"\.sys" /c:"\.exe" /c:"\.dll"') do (
ECHO %%c 2>NUL
IF NOT EXIST "%amd64Dir%" (MD "%amd64Dir%" 2>NUL)
COPY /y "%%c" "%amd64Dir%" 2>NUL
)
for /f %%d in ('dir /b /s "%~dp0%KvmDriver%\%KvmSystem%\arm64" 2^>NUL ^| FINDSTR /c:"\.cat" /c:"\.inf" /c:"\.sys" /c:"\.exe" /c:"\.dll"') do (
ECHO %%d 2>NUL
IF NOT EXIST "%arm64Dir%" (MD "%arm64Dir%" 2>NUL)
COPY /y "%%d" "%arm64Dir%" 2>NUL
)
for /f %%e in ('dir /b /s "%~dp0%KvmDriver%\%KvmSystem%\x86" 2^>NUL^| FINDSTR /c:"\.cat" /c:"\.inf" /c:"\.sys" /c:"\.exe" /c:"\.dll"') do (
ECHO %%e 2>NUL
IF NOT EXIST "%x86Dir%" (MD "%x86Dir%" 2>NUL)
COPY /y "%%e" "%x86Dir%" 2>NUL
)
goto:eof
exit

复制代码

当然，假如你也有需要对文件夹细分类的需要，可以参考此代码，我是反复套循环实现的，利用批处理搞这玩意真的很难了。

下载链接：http://d.nat.ee/bat/virtio-win-driver-Classify.cmd

atmo · 发表于 2021-11-2 18:40:22

支持大佬！zsbd

optimism · 发表于 2021-11-2 18:41:14

技术贴顶一下

b66667777 · 发表于 2021-11-2 18:46:47

支持一下

冷心 · 发表于 2021-11-2 19:03:41

想法极好啊，给楼主点赞，楼主的DD包很好用

gick · 发表于 2021-11-2 19:41:26

不懂，帮顶。

* 这个世上有很多事是解释不通的

老猹 · 发表于 2021-11-2 20:35:38

支持技术贴，大佬的win包很好用。

telnetpig · 发表于 2021-11-2 20:47:00

支持一下

KuYeHQ · 发表于 2021-11-2 20:49:16

我选择白票大佬的

ncnc · 发表于 2021-11-2 21:02:06

大佬 CC 家的用你的哪个脚本DD啊

		自动登录	找回密码
密码			注册